CMakeLists.txt

# Copyright 2020 University of Liège
# 
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
# 
#     http://www.apache.org/licenses/LICENSE-2.0
# 
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

# ----------------------------------------------------------------------------
PROJECT(Waves)
# ----------------------------------------------------------------------------
CMAKE_MINIMUM_REQUIRED(VERSION 3.1)
IF(${CMAKE_VERSION} VERSION_GREATER "3.14.0") # we might want to update the project and use the NEW behavior here
    cmake_policy(SET CMP0078 OLD)
    cmake_policy(SET CMP0086 OLD)
ENDIF()

SET(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin CACHE PATH
                        "Single output directory for building all libraries.")
SET(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin CACHE PATH
                        "Single output directory for building all executables.")
MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)

IF(NOT CMAKE_BUILD_TYPE)
    SET( CMAKE_BUILD_TYPE "Release" CACHE STRING 
         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
         FORCE)
ENDIF(NOT CMAKE_BUILD_TYPE)
MESSAGE(STATUS "CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")

LIST(APPEND CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMake")

# -- GENERAL OPTIONS

# print OS
MESSAGE(STATUS "CMAKE_SYSTEM_NAME=\"${CMAKE_SYSTEM_NAME}\"")
MESSAGE(STATUS "CMAKE_CXX_COMPILER_ID=${CMAKE_CXX_COMPILER_ID}")

# (de)activate modules
OPTION(WAVES_USE_FLOW        "Compile flow module"             ON)
OPTION(WAVES_USE_HEAT        "Compile heat module"             ON)
OPTION(WAVES_USE_MIRRORS     "Compile mirrors module"          ON)
OPTION(WAVES_USE_KATOPTRON   "Compile katoptron module"        ON)
OPTION(WAVES_USE_PARAMS      "Compile params module"           ON)
OPTION(WAVES_USE_TLNOS       "Compile tlnos module"            ON)
OPTION(WAVES_USE_WAVES       "Compile waves module"            ON)
# (de)activate extensions
OPTION(WAVES_USE_TBOXVTK     "Compile tboxVtk module"          ON)
# (de)activate external packages
OPTION(WAVES_USE_MKL         "Compile with Intel MKL"          ON)
OPTION(WAVES_USE_MUMPS       "Compile with MUMPS"              ON)

# --- Disable some Options on Windows
IF(WIN32)
    # Trilinos is not available on Windows
    MESSAGE("Disabling TRILINOS on Windows")
    SET(WAVES_USE_KATOPTRON OFF CACHE BOOL "" FORCE)
    SET(WAVES_USE_TLNOS OFF CACHE BOOL "" FORCE)
ENDIF()

# macros/fcts
INCLUDE(fwkMacros)

# -- C++11
SET(CMAKE_CXX_STANDARD 11) # newer way to set C++11 (requires cmake>=3.1)
SET(CMAKE_CXX_STANDARD_REQUIRED ON)

# Set specific languages flags
IF((CMAKE_CXX_COMPILER_ID MATCHES "GNU") OR (CMAKE_CXX_COMPILER_ID MATCHES "Intel"))
    IF(NOT APPLE)
        SET(CMAKE_SHARED_LINKER_FLAGS "-Wl,--no-as-needed")
    ENDIF()
    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall") # add verbosity
    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fopenmp -Wno-unknown-pragmas -Wno-sign-compare") # merge trilinos
ELSEIF(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
    ADD_DEFINITIONS(-D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_DEPRECATE)
    ADD_DEFINITIONS(-D_USE_MATH_DEFINES) # otherwise M_PI is undefined
    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")  # parallel build with MSVC
    #SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")  # add verbosity
ELSEIF(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-deprecated-register")
    #SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Weverything") # add verbosity
ENDIF()

# -- OS related (from Kim)
IF(APPLE)
    SET(CMAKE_MACOSX_RPATH TRUE)
ENDIF()

# -- Search for Python
IF (CMAKE_VERSION VERSION_LESS 3.12.0)
    FIND_PACKAGE(PythonInterp 3.6 REQUIRED)
    FIND_PACKAGE(PythonLibs 3.6 REQUIRED)
ELSE()
    find_package (Python3 COMPONENTS Interpreter Development)
    # use Python3_ROOT_DIR if wrong python found (e.g. anaconda)
    SET(PYTHON_EXECUTABLE ${Python3_EXECUTABLE})
    SET(PYTHON_LIBRARIES ${Python3_LIBRARIES})
    SET(PYTHON_INCLUDE_PATH ${Python3_INCLUDE_DIRS}) 
    SET(PYTHONLIBS_VERSION_STRING ${Python3_VERSION})     
ENDIF()
MESSAGE(STATUS "PYTHON_EXECUTABLE:FILEPATH=${PYTHON_EXECUTABLE}")
MESSAGE(STATUS "PYTHON_LIBRARIES:FILEPATH=${PYTHON_LIBRARIES}")
MESSAGE(STATUS "PYTHON_INCLUDE_PATH:FILEPATH=${PYTHON_INCLUDE_PATH}")
MESSAGE(STATUS "PYTHON_FRAMEWORK_INCLUDES=${PYTHON_FRAMEWORK_INCLUDES}")
MESSAGE(STATUS "PYTHONLIBS_VERSION_STRING=${PYTHONLIBS_VERSION_STRING}")
MESSAGE(STATUS "Python_FRAMEWORKS=${Python_FRAMEWORKS}")

# -- Search for SWIG
FIND_PACKAGE(SWIG REQUIRED)
IF(CMAKE_GENERATOR MATCHES "Visual Studio") # not MSVC because of nmake & jom
    SET(CMAKE_SWIG_OUTDIR "${EXECUTABLE_OUTPUT_PATH}/$(Configuration)/")
ELSE()
    SET(CMAKE_SWIG_OUTDIR "${EXECUTABLE_OUTPUT_PATH}")
ENDIF()

# -- Doxygen (https://vicrucann.github.io/tutorials/quick-cmake-doxygen/)
# check if Doxygen is installed
FIND_PACKAGE(Doxygen)
IF(DOXYGEN_FOUND)
    # set input and output files
    SET(DOXYGEN_IN ${PROJECT_SOURCE_DIR}/Doxyfile.in)
    SET(DOXYGEN_OUT ${PROJECT_BINARY_DIR}/Doxyfile)

    # request to configure the file
    CONFIGURE_FILE(${DOXYGEN_IN} ${DOXYGEN_OUT} @ONLY)
    #message("Doxygen build started")

    # note the option ALL which allows to build the docs together with the application
    # "make dox" rebuilds the doc
    ADD_CUSTOM_TARGET( dox #ALL
        COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_OUT}
        WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
        COMMENT "Generating API documentation with Doxygen"
        VERBATIM )
ELSE()
    MESSAGE("Doxygen need to be installed to generate the doxygen documentation")
ENDIF()

# -- Configure file (for SWIG to detect definitions)
CONFIGURE_FILE(${PROJECT_SOURCE_DIR}/waves_config.h.in
               ${PROJECT_BINARY_DIR}/waves_config.h)
INCLUDE_DIRECTORIES(${PROJECT_BINARY_DIR}) # to find "waves_config.h"

# -- CTest
ENABLE_TESTING()

# -- Sub directories

ADD_SUBDIRECTORY( fwk )
ADD_SUBDIRECTORY( tbox )

IF(WAVES_USE_TBOXVTK)
    ADD_SUBDIRECTORY( tboxVtk )
ENDIF()

IF(WAVES_USE_FLOW)
    ADD_SUBDIRECTORY( flow )
ENDIF()

IF(WAVES_USE_HEAT)
    ADD_SUBDIRECTORY( heat )
ENDIF()

IF(WAVES_USE_MIRRORS)
    ADD_SUBDIRECTORY( mirrors )
ENDIF()

IF(WAVES_USE_KATOPTRON)
    ADD_SUBDIRECTORY( katoptron )
ENDIF()

IF(WAVES_USE_PARAMS)
    ADD_SUBDIRECTORY( params )
ENDIF()

IF(WAVES_USE_TLNOS)
    ADD_SUBDIRECTORY( tlnos )
ENDIF()

IF(WAVES_USE_WAVES)
    ADD_SUBDIRECTORY( waves )
ENDIF()

# -- Packaging
# set paths and target names
SET(WAVES_INCLUDE_DIRS "${PROJECT_SOURCE_DIR}/fwk/src" "${PROJECT_SOURCE_DIR}/tbox/src" "${PROJECT_BINARY_DIR}")
SET(WAVES_SWIG_DIRS "${PROJECT_SOURCE_DIR}/fwk/_src" "${PROJECT_SOURCE_DIR}/tbox/_src")
SET(WAVES_LIBRARIES fwk tbox)
# export target config
EXPORT(TARGETS ${WAVES_LIBRARIES} FILE "${PROJECT_BINARY_DIR}/wavesTargets.cmake")
# generate configuration file with absolute paths
CONFIGURE_FILE(waves-config.cmake.in "${PROJECT_BINARY_DIR}/waves-config.cmake" @ONLY)